;;---------------------=={ String Wrap }==--------------------;;
;;                                                            ;;
;;  Breaks a string at spaces (if possible) into a list of    ;;
;;  substrings of a specified length or less.                 ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright © 2011 - www.lee-mac.com       ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  str - String to wrap to a specific length                 ;;
;;  len - Maximum length of each substring                    ;;
;;------------------------------------------------------------;;
;;  Returns:  List of substrings of specified length or less  ;;
;;------------------------------------------------------------;;

(defun LM:StringWrap ( str len / pos )
    (if (< len (strlen str))
        (cons
            (substr str 1
                (cond
                    (   (setq pos (vl-string-position 32 (substr str 1 len) nil t)))
                    (   (setq pos (1- len)) len)
                )
            )
            (LM:StringWrap (substr str (+ 2 pos)) len)
        )
        (list str)
    )
)

_$ (LM:StringWrap "This is a very long string which needs to be wrapped." 20)

("This is a very long" "string which needs" "to be wrapped.")